Refactor assets and config directory

src_assets/windows/assets/shaders/directx/ConvertUVPS.hlsl

@@ -0,0 +1,33 @@
+Texture2D image : register(t0);
+
+SamplerState def_sampler : register(s0);
+
+struct FragTexWide {
+	float3 uuv : TEXCOORD0;
+};
+
+cbuffer ColorMatrix : register(b0) {
+	float4 color_vec_y;
+	float4 color_vec_u;
+	float4 color_vec_v;
+	float2 range_y;
+	float2 range_uv;
+};
+
+//--------------------------------------------------------------------------------------
+// Pixel Shader
+//--------------------------------------------------------------------------------------
+float2 main_ps(FragTexWide input) : SV_Target
+{
+	float3 rgb_left = image.Sample(def_sampler, input.uuv.xz).rgb;
+	float3 rgb_right = image.Sample(def_sampler, input.uuv.yz).rgb;
+	float3 rgb = (rgb_left + rgb_right) * 0.5;
+	
+	float u = dot(color_vec_u.xyz, rgb) + color_vec_u.w;
+	float v = dot(color_vec_v.xyz, rgb) + color_vec_v.w;
+
+	u = u * range_uv.x + range_uv.y;
+	v = v * range_uv.x + range_uv.y;
+
+	return float2(u, v * 224.0f/256.0f + 0.0625);
+}

src_assets/windows/assets/shaders/directx/ConvertUVVS.hlsl

@@ -0,0 +1,29 @@
+struct VertTexPosWide {
+	float3 uuv : TEXCOORD;
+	float4 pos : SV_POSITION;
+};
+
+cbuffer info : register(b0) {
+	float width_i;
+};
+
+//--------------------------------------------------------------------------------------
+// Vertex Shader
+//--------------------------------------------------------------------------------------
+VertTexPosWide main_vs(uint vI : SV_VERTEXID)
+{
+	float idHigh = float(vI >> 1);
+	float idLow = float(vI & uint(1));
+
+	float x = idHigh * 4.0 - 1.0;
+	float y = idLow * 4.0 - 1.0;
+
+	float u_right = idHigh * 2.0;
+	float u_left = u_right - width_i;
+	float v = 1.0 - idLow * 2.0;
+
+	VertTexPosWide vert_out;
+	vert_out.uuv = float3(u_left, u_right, v);
+	vert_out.pos = float4(x, y, 0.0, 1.0);
+	return vert_out;
+}

src_assets/windows/assets/shaders/directx/ConvertYPS.hlsl

@@ -0,0 +1,25 @@
+Texture2D image : register(t0);
+
+SamplerState def_sampler : register(s0);
+
+cbuffer ColorMatrix : register(b0) {
+	float4 color_vec_y;
+	float4 color_vec_u;
+	float4 color_vec_v;
+	float2 range_y;
+	float2 range_uv;
+};
+
+struct PS_INPUT
+{
+	float4 pos : SV_POSITION;
+	float2 tex : TEXCOORD;
+};
+
+float main_ps(PS_INPUT frag_in) : SV_Target
+{
+	float3 rgb = image.Sample(def_sampler, frag_in.tex, 0).rgb;
+	float y = dot(color_vec_y.xyz, rgb);
+
+	return y * range_y.x + range_y.y;
+}

src_assets/windows/assets/shaders/directx/ScenePS.hlsl

@@ -0,0 +1,14 @@
+Texture2D image : register(t0);
+
+SamplerState def_sampler : register(s0);
+
+struct PS_INPUT
+{
+	float4 pos : SV_POSITION;
+	float2 tex : TEXCOORD;
+};
+
+float4 main_ps(PS_INPUT frag_in) : SV_Target
+{
+	return image.Sample(def_sampler, frag_in.tex, 0);
+}

src_assets/windows/assets/shaders/directx/SceneVS.hlsl

@@ -0,0 +1,22 @@
+struct PS_INPUT
+{
+	float4 pos : SV_POSITION;
+	float2 tex : TEXCOORD;
+};
+
+PS_INPUT main_vs(uint vI : SV_VERTEXID)
+{
+	float idHigh = float(vI >> 1);
+	float idLow = float(vI & uint(1));
+
+	float x = idHigh * 4.0 - 1.0;
+	float y = idLow * 4.0 - 1.0;
+
+	float u = idHigh * 2.0;
+	float v = 1.0 - idLow * 2.0;
+
+	PS_INPUT vert_out;
+	vert_out.pos = float4(x, y, 0.0, 1.0);
+	vert_out.tex = float2(u, v);
+	return vert_out;
+}